FStat

   

Declaration:

Function FStat (Path : Pathstr; Var Info : stat) : Boolean;

Description:

FStat gets information about the file specified in Path, and stores it in Info, which is of type stat.

The function returns True if the call was succesfull, False if the call failed.

Errors:

LinuxError is used to report errors.

sys_enoent

Path does not exist.

See also:

FSStat, LStat, stat (2)

Example

program example28;

{ Program to demonstrate the FStat function. }

uses linux;
    
var f : text;    
    i : byte;
    info : stat;
    
begin
  { Make a file }
  assign (f,'test.fil');
  rewrite (f);
  for i:=1 to 10 do writeln (f,'Testline # ',i);
  close (f);
  { Do the call on made file. }
  if not fstat ('test.fil',info) then 
     begin
     writeln('Fstat failed. Errno : ',linuxerror);
     halt (1);
     end;
  writeln;
  writeln ('Result of fstat on file ''test.fil''.');
  writeln ('Inode   : ',info.ino);
  writeln ('Mode    : ',info.mode);
  writeln ('nlink   : ',info.nlink);
  writeln ('uid     : ',info.uid);
  writeln ('gid     : ',info.gid);
  writeln ('rdev    : ',info.rdev);
  writeln ('Size    : ',info.size);
  writeln ('Blksize : ',info.blksze);
  writeln ('Blocks  : ',info.blocks);
  writeln ('atime   : ',info.atime);
  writeln ('mtime   : ',info.mtime);
  writeln ('ctime   : ',info.ctime);
  { Remove file }  
  erase (f);    
end.