Calculation of Amplitudes Using Helicity Eigenstates With Mass
Set of Programs to explain how to use traces to obtain helicity amplitudes
Author: Jorge C. Romao
Last Update: 04/11/2021

1- Definitions

We use the general expressions given in Eqs. (4.65)  and (4.66) of Thomson 

We should keep in mind that with the usual kinematics for the CM the angles for the 4 particles are

p1: θ  = 0, ϕ = 0
p2: θ  = π, ϕ = π
p3: θ , ϕ = 0
p4: θ → π - θ, ϕ = π 

Also rs = (Sqrt[s])

Kinematics for 1 + 2 -> 3 + 4 with m1=m2, m3=m4 in the CM

E1=rs/2;
E2=rs/2;
E3=rs/2;
E4=rs/2;
m2=m1;
m4=m3;
beta2=beta1;
beta4=beta3;
SimpMasses= {m3^2->rs^2/4(1-beta3^2),m1^2->rs^2/4(1-beta1^2)};
SimpBetas={beta1->Sqrt[1-4*m1^2/rs^2],beta3->Sqrt[1-4*m3^2/rs^2]}

Definition of the helicity spinors

uSpinorp1=Function[h,If[h>0,Sqrt[E1+m1]{1,0,beta1 *E1/(E1+m1),0},Sqrt[E1+m1]{0,1,0,-beta1*E1/(E1+m1)}]];

vSpinorp2=Function[h,If[h>0,Sqrt[E2+m2]{beta2*E2/(E2+m2),0,-1,0},Sqrt[E2+m2]{0,-beta2*E2/(E2+m2),0,-1}]];

uSpinorp3=Function[h,If[h>0,Sqrt[E3 + m3]{Cos[θ/2],Sin[θ/2],beta3 E3/(E3+m3)Cos[θ/2],beta3 E3/(E3+m3)Sin[θ/2]},Sqrt[E3+m3]{-Sin[θ/2],Cos[θ/2],beta3 E3/(E3+m3) Sin[θ/2],- beta3 E3/(E3+m3) Cos[θ/2]}]];

vSpinorp4=Function[h,If[h>0,Sqrt[E4+m4]{beta4 E4/(E4+m4) Cos[θ/2],beta4 E4 /(E4+m4)Sin[θ/2],-Cos[θ/2],-Sin[θ/2]},Sqrt[E4+m4]{beta4 E4/(E4+m4) Sin[θ/2],-beta4 E4/(E4+m4)Cos[θ/2],Sin[θ/2],-Cos[θ/2]}]];

Definition of Dirac Gamma Matrices

G0={{1,0,0,0},{0,1,0,0},{0,0,-1,0},{0,0,0,-1}};

G1={{0,0,0,1},{0,0,1,0},{0,-1,0,0},{-1,0,0,0}};

G2={{0,0,0,-I},{0,0,I,0},{0,I,0,0},{-I,0,0,0}};

G3={{0,0,1,0},{0,0,0,-1},{-1,0,0,0},{0,1,0,0}};

GammaVec={G0,G1,G2,G3};

G5 ={{0,0,1,0},{0,0,0,1},{1,0,0,0},{0,1,0,0}};

Id=IdentityMatrix[4];

Definition of scalar product in Minkowski space

dot=Function[{v1,v2},v1[[1]]v2[[1]]-Sum[v1[[i]]v2[[i]],{i,2,4}]];

s-channel vector currents

We have two different types of currents with four different helicity combinations each, one for the initial sate and another for the final state. However we just consider one of those because we take 1 and 3 as the particles and 2 and 4 as the anti-particles. With masses all 16 helicity combinations will be non-zero.

Ju1v2

Ju1v2=Function[{h1,h2},Table[vSpinorp2[h2].G0. GammaVec[[i]].uSpinorp1[h1],{i,1,4}]];

Ju1v2[1,1]/. SimpBetas//Simplify

Ju1v2[-1,-1]/. SimpBetas//Simplify

Ju1v2[1,-1]/. SimpBetas//Simplify

Ju1v2[-1,1]/. SimpBetas//Simplify

Ju3v4

Ju3v4=Function[{h3,h4},(Table[uSpinorp3[h3].G0. GammaVec[[i]].vSpinorp4[h4],{i,1,4}])//Simplify];

Ju3v4[1,1]/. SimpBetas//Simplify

Ju3v4[-1,-1]/. SimpBetas//Simplify

Ju3v4[1,-1]/. SimpBetas//Simplify

Ju3v4[-1,1]/. SimpBetas//Simplify

2. Calculations of various processes in the CM frame in QED

(e^(- )) (e^(+ ))→ (μ^(- )) (μ^(+ ))

The amplitude is given by                       M[h1,h2,h3,h4] = - e^2/s Ju1v2 . Ju3v4

M=Function[{h1,h2,h3,h4}, e^2/rs^2 dot[Ju1v2[h1,h2],Ju3v4[h3,h4]]];

M[1,1,1,1]/. SimpBetas//Simplify

M[1,-1,1,1]/. SimpBetas//Simplify

M[-1,1,1,1]/. SimpBetas//Simplify

M[-1,-1,1,1]/. SimpBetas//Simplify

M[1,1,1,-1]/. SimpBetas//Simplify

M[1,-1,1,-1]/. SimpBetas//Simplify

M[-1,1,1,-1]/. SimpBetas//Simplify

M[-1,-1,1,-1]/. SimpBetas//Simplify

M[1,1,-1,1]/. SimpBetas//Simplify

M[1,-1,-1,1]/. SimpBetas//Simplify

M[-1,1,-1,1]/. SimpBetas//Simplify

M[-1,-1,-1,1]/. SimpBetas//Simplify

M[1,1,-1,-1]/. SimpBetas//Simplify

M[1,-1,-1,-1]/. SimpBetas//Simplify

M[-1,1,-1,-1]/. SimpBetas//Simplify

M[-1,-1,-1,-1]/. SimpBetas//Simplify

Msqavg

MsqAverage1=1/4 Sum[M[h1,h2,h3,h4]^2,{h1,-1,1,2},{h2,-1,1,2},{h3,-1,1,2},{h4,-1,1,2}]/. SimpBetas//Simplify

MsqAverage2= MsqAverage1 /. SimpMasses//Simplify

MsqAverageWithMasses=MsqAverage2/. Cos[2 θ]-> -1 + 2 Cos[θ]^2//Simplify

MSqAverageMass1Zero=MsqAverageWithMasses/.{beta1->1}

MSqAverageMassesZero=MsqAverageWithMasses/.{beta1->1,beta3->1}

3. Helicity Projectors

P1

P1=Function[h,1/2 ( Id + h G5.(G0 beta1 - G3) rs/(2 m1))]

P1[-1].uSpinorp1[-1]-uSpinorp1[-1]/. SimpBetas//Simplify

P1[1].uSpinorp1[-1]/. SimpBetas//Simplify

P2

P2=Function[h,1/2 ( Id + h G5.(G0 beta1 + G3) rs/(2 m1))]

P2[1].vSpinorp2[1]-vSpinorp2[1]/. SimpBetas//Simplify

P2[-1].vSpinorp2[1]/. SimpBetas//Simplify

P3

P3=Function[h,1/2  (Id + ((G5.G0) beta3 - (G5.G1) Sin[θ]-(G5.G3) Cos[θ]) h rs/(2 m3))]

P3[1].uSpinorp3[1]-uSpinorp3[1]/. SimpBetas//Simplify

P3[1].uSpinorp3[-1]/. SimpBetas//Simplify

P4

P4=Function[h,1/2 ( Id + ((G5.G0) beta3 + (G5.G1) Sin[θ]+(G5.G3) Cos[θ]) h rs/(2 m3))]

P4[-1].vSpinorp4[-1]-vSpinorp4[-1]/. SimpBetas//Simplify

P4[1].vSpinorp4[-1]/. SimpBetas//Simplify

4. Scalar products with spin vectors

p1=rs/2{1,0,0,beta1};
p2=rs/2{1,0,0,-beta1};
p3=rs/2{1,beta3 Sin[θ],0,beta3 Cos[θ]};
p4=rs/2{1,-beta3 Sin[θ],0,-beta3 Cos[θ]};
s1=rs/(2 m1){beta1,0,0,1};
s2=rs/(2m1){beta1,0,0,-1};
s3=rs/(2m3){beta3,Sin[θ],0, Cos[θ]};
s4=rs/(2m3){beta3,-Sin[θ],0, -Cos[θ]};

dot[s4,p2]//Simplify

5. Helicity Projectors and m->0 Limit

PL and PR

PL=1/2(Id - G5);

PR=1/2(Id+G5);

P3

OL3=1/2 (1- slash{s})  OR3=1/2 (1 + slash{s})

OL3=Function[h,1/2  (Id -h(G0 beta3 - G1 Sin[θ]-G3 Cos[θ])  rs/(2 m3))];

OR3=Function[h,1/2  (Id +h(G0 beta3 - G1 Sin[θ]-G3 Cos[θ])  rs/(2 m3))];

Series[(OL3[1].uSpinorp3[1]/. SimpBetas//Simplify),{m3,0,1}]

Series[(OR3[1].uSpinorp3[1]/. SimpBetas//Simplify),{m3,0,1}]

Series[(PR.uSpinorp3[1] /. SimpBetas//Simplify),{m3,0,1}]

Series[(PL.uSpinorp3[1] /. SimpBetas//Simplify),{m3,0,1}]

Series[(OL3[1].uSpinorp3[-1]/. SimpBetas//Simplify),{m3,0,1}]

Series[(OR3[1].uSpinorp3[-1]/. SimpBetas//Simplify),{m3,0,1}]

Series[(PR.uSpinorp3[-1] /. SimpBetas//Simplify),{m3,0,1}]

Series[(PL.uSpinorp3[-1] /. SimpBetas//Simplify),{m3,0,1}]

TimeUsed[]